实例需求：工作表中的数据表如下图所示。
现在需要针对每个类别（Category）添加汇总行，如第4行所示，注意每个类别包含的数据行数不确定。
示例代码如下。
Sub Demo()
Dim SumA As Double, SumB As Double, i As Long, j As Long, iR As Long
Const S_CELL = "A1"
Dim arrData
arrData = Range(S_CELL).CurrentRegion.Value
Dim ColCnt As Long
ColCnt = UBound(arrData, 2)
Dim arrRes()
ReDim arrRes(1 To UBound(arrData) * 2, 1 To ColCnt)
For i = LBound(arrData) + 1 To UBound(arrData)
If Len(arrData(i, 1)) > 0 Then
If i > 2 Then
iR = iR + 1
arrRes(iR, 7) = "Total"
arrRes(iR, 8) = SumA
arrRes(iR, 9) = SumB
End If
SumA = arrData(i, 8)
SumB = arrData(i, 9)
Else
SumA = arrData(i, 8) + SumA
SumB = arrData(i, 9) + SumB
End If
iR = iR + 1
For j = 1 To ColCnt
arrRes(iR, j) = arrData(i, j)
Next
Next
iR = iR + 1
arrRes(iR, 7) = "Total"
arrRes(iR, 8) = SumA
arrRes(iR, 9) = SumB
Range(S_CELL).Offset(1).Resize(iR, ColCnt).Value = arrRes
End Sub
【代码解析】
第3行代码定义常量为数据源表格的起始单元格。
第5行代码将数据表加载到数组中。
第7行代码获取数据表的总列数。
第9行代码为数组分配存储空间，用于转换后的数据。
第10~28行代码循环处理数据。
第11行代码判断Serial列是否为空。如果不为空，说明该行为一个新Serial的起始行。
第12行代码判断行号是否大于2。
如果满足条件，则第13至16行代码在结果数组中插入合计行，第18~19行代码初始化SumA和SumB。如果不满足条件，那么第21~22行代码累加SumA和SumB。
第24~27行代码将原始数据行写入结果数组中。
第29~32行代码将最后一个Serial的汇总数据写入结果数组中。
第33行代码将结果数组写入工作表。注意：由于源数据表包含标题行，因此代码中需要使用Offset(1)，将回写单元格区域的起始单元格向下偏移一行。